4.8.4. Поиск файлов

Найти нужный файл на диске намного сложнее, чем просто открыть его, — для этого требуются две функции при работе с короткими именами (найти первый файл и найти следующий файл) и три — при работе с длинными именами в DOS 7.0 (найти первый файл, найти следующий файл, прекратить поиск).

Функция DOS 4Eh — Найти первый файл

Вызов этой функции заполняет данными область памяти DTA (область передачи данных), которая начинается по умолчанию со смещения 0080h от начала блока данных PSP (при запуске СОМ- и ЕХЕ-программ сегменты DS и ES содержат сегментный адрес начала PSP), но ее можно переопределить с помощью функции 1Ah.

Функция DOS 1Ah — Установить область DTA

Функции поиска файлов заполняют DTA следующим образом:

+00h: байт — биты 0 – 6: ASCII-код буквы диска; бит 7: диск сетевой

+01h: 11 байт — маска поиска (без пути)

+0СН: байт — атрибуты для поиска

+0Dh: слово — порядковый номер файла в каталоге

+0Fh: слово — номер кластера начала внешнего каталога

+11h: 4 байта — зарезервировано

+15h: байт — атрибут найденного файла

+16h: слово — время создания файла в формате DOS:

биты 15 – 11: час (0 — 23)

биты 10 – 5: минута

биты 4 – 0: номер секунды, деленный на 2 (0 – 30)

+18h: слово — дата создания файла в формате DOS:

биты 15 – 9: год, начиная с 1980

биты 8 – 5: месяц

биты 4 – 0: день

+1Ah: 4 байта — размер файла

+1Eh: 13 байт — ASCIZ-имя найденного файла с расширением

После того как DTA заполнена данными, для продолжения поиска следует вызывать функцию 4Fh, пока не будет возвращена ошибка.

Функция DOS 4Fh — Найти следующий файл

Для случая длинных имен файлов (LFN) употребляется набор из трех подфункций функции DOS 71h, которые можно использовать, только если запущен IFSmgr (всегда запускается при обычной установке Windows 95, но не запускается, например, с загрузочной дискеты MS-DOS 7.0).

Функция LFN 4Eh — Найти первый файл с длинным именем

Если файл, подходящий под маску и атрибуты поиска, найден, область данных по адресу ES:DI заполняется следующим образом:

+00h: 4 байта — атрибуты файла

биты 0 – 6: атрибуты файла DOS

бит 8: временный файл

+04h: 8 байт — время создания файла

+0Ch: 8 байт — время последнего доступа к файлу

+14h: 8 байт — время последней модификации файла

+1Ch: 4 байта — старшее двойное слово длины файла

+20h: 4 байта — младшее двойное слово длины файла

+24h: 8 байт — зарезервировано

+2Ch: 260 байт — ASCIZ-имя файла длинное

+130h: 14 байт — ASCIZ-имя файла короткое

Причем даты создания/доступа/модификации записываются в одном из двух форматов, в соответствии со значением SI при вызове функции. Windows-формат — 64-битное число 100-наносекундных интервалов с 1 января 1601 года, а если используется DOS-формат — в старшее двойное слово записывается DOS-дата, а в младшее — DOS-время.

Функция LFN 4Fh — Найти следующий файл

Функция LFN A1h — Закончить поиск файла

В качестве примера программы, использующей многие из функций работы с файлами, рассмотрим программу, заменяющую русские буквы «Н» на латинские «Н» во всех файлах с расширением .ТХТ в текущем каталоге (такая замена требуется для всех текстов, которые будут пересылаться через сеть Fidonet, программное обеспечение которой воспринимает русскую букву «Н» как управляющий символ).

; fidoh.asm
; заменяет русские "Н" на латинские "Н" во всех файлах с расширением .ТХТ
; в текущем каталоге
        .model     tiny
        .code
        org        100h                ; СОМ-файл
start:
        mov        ah,4Eh              ; поиск первого файла
        xor        cx,cx               ; не системный, не каталог и т.д.
        mov        dx,offset filespec  ; маска для поиска в DS:DX
file_open:
        int        21h
        jc         no_more_files       ; если CF = 1 - файлы кончились

        mov        ax,3D02h            ; открыть файл для чтения и записи
        mov        dx,80h+1Eh          ; смещение DTA + смещение имени файла
        int        21h                 ; от начала DTA
        jc         find_next           ; если файл не открылся - перейти
                                       ; к следующему
        mov        bx,ax               ; идентификатор файла в ВХ
        mov        cx,1                ; считывать один байт
        mov        dx,offset buffer    ; начало буфера - в DX
read_next:
        mov        ah,3Fh              ; чтение файла
        int        21h
        jc         find_next           ; если ошибка - перейти к следующему
        dec        ах                  ; если АХ = 0 - файл кончился -
        js         find_next           ; перейти к следующему
        cmp        byte ptr buffer,8Dh ; если не считана русская "Н",
        jne        read_next           ; считать следующий байт,
        mov        byte ptr buffer,48h ; иначе - записать в буфер
                                       ; латинскую букву "Н"
        mov        ax,4201h            ; переместить указатель файла от текущей
        dec        cx                  ; позиции назад на 1
        dec        cx                  ; CX = FFFFh
        mov        dx,cx               ; DX = FFFFh
        int        21h
        mov        ah,40h              ; записать в файл
        inc        cx
        inc        cx                  ; один байт (СХ = 1)
        mov        dx,offset buffer    ; из буфера в DS:DX
        int        21h
        jmp        short read_next     ; считать следующий байт

find_next:
        mov        ah,3Eh              ; закрыть предыдущий файл
        int        21h
        mov        ah,4Fh              ; найти следующий файл
        mov        dx,80h              ; смещение DTA от начала PSP
        jmp        short file_open

no_more_files:                         ; если файлы кончились,
        ret                            ; выйти из программы

filespec      db   "*.txt",0           ; маска для поиска
buffer label  byte                     ; буфер для чтения/записи -
        end        start               ; за концом программы

п»ї "target=_blank><\/a>") //-->